LibreOffice 24.8 Bantuan
Kategori ini mengandung fungsi Informasi.
Data dalam tabel berikut sebagai dasar dari beberapa contoh dalam keterangan fungsi:
| C | D | |
|---|---|---|
| 2 | x value | y value | 
| 3 | -5 | -3 | 
| 4 | -2 | 0 | 
| 5 | -1 | 1 | 
| 6 | 0 | 3 | 
| 7 | 2 | 4 | 
| 8 | 4 | 6 | 
| 9 | 6 | 8 | 
Mengembalikan informasi pada alamat, pemformatan atau isi sebuah sel.
CELL("InfoType" [; Reference])
InfoType adalah karakter string yang menentukan tipe informasi. Karakter string selalu dalam bahasa Inggris. Huruf besar atau kecil adalah pilihan.
| Jenis_info | Arti | 
|---|---|
| COL | Menghasilkan nomor dari kolom yang direferensikan. =CELL("COL";D2) mengembalikan 4. | 
| ROW | Menghasilkan nomor dari baris yang direferensikan. =CELL("ROW";D2) mengembalikan 2. | 
| SHEET | Menghasilkan nomor dari lembar yang dirujuk. =CELL("Sheet";Sheet3.D2) mengembalikan 3. | 
| ADDRESS | Menghasilkan alamat absolut dari sel yang direferensikan. =CELL("ADDRESS";D2) mengembalikan $D$2. =CELL("ADDRESS";Sheet3.D2) mengembalikan $Sheet3.$D$2. =CELL("ALAMAT";'X:\dr\test.ods'#$Sheet1.D2) mengembalikan 'file:///X:/dr/test.ods'#$Sheet1.$D$2. | 
| FILENAME | Menghasilkan nama berkas dan nomor lembar dari sel yang dirujuk. =CELL("FILENAME";D2) mengembalikan 'file:///X:/dr/own.ods'#$Sheet1, jika rumus didalam dokumen saat ini X:\dr\own.ods berada di Lembar1 =CELL("FILENAME";'X:\dr\test.ods'#$Sheet1.D2) mengembalikan 'file:///X:/dr/test.ods'#$Sheet1. | 
| COORD | Mengembalikan alamat lengkap sel dalam notasi Lotus™. =CELL("COORD"; D2) mengembalikan $A:$D$2. =CELL("COORD"; Sheet3.D2) mengembalikan $C:$D$2. | 
| CONTENTS | Menghasilkan isi dari sel yang direferensikan, tanpa pemformatan apa pun. | 
| TYPE | Menghasilkan jenis dari isi sel. b = blank. sel kosong l = label. Teks, hasil formula sebagai teks v = value. Nilai, hasil formula sebagai angka/bilangan | 
| WIDTH | Mengembalikan lebar dari kolom yang direferensi. Unit itu adalah bilangan nol (0) yang sesuai kedalam kolom dalam teks baku atau ukuran baku. | 
| PREFIX | Menghasilkan perataan dari sel yang direferensikan. ' = rata kiri " = rata kanan ^ = rata tengah \ = berulang (saat ini tak aktif) | 
| PROTECT | Menghasilkan status dari proteksi sel. 1 = sel diproteksi 0 = sel tidak diproteksi | 
| FORMAT | Menghasilkan string karakter yang mengindikasikan format angka. , = bilangan dengan pemisah ribuan F = bilangan tanpa pemisah ribuan C = format mata uang S = representasi eksponensial, sebagai contoh, 1.234+E56 P = persentase Pada format diatas, bilangan desimal yang ditempatkan setelah pemisah desimal diberikan sebagai bilangan. Contoh: format bilangan #,mengembalikan ##0.0 , 1 dan format bilangan 00.000% mengembalikan P3 D1 = MMM-D-YY, MM-D-YY dan format lainnya yang serupa D2 = DD-MM D3 = MM-YY D4 = DD-MM-YYYY HH:MM:SS D5 = MM-DD D6 = HH:MM:SS AM/PM D7 = HH:MM AM/PM D8 = HH:MM:SS D9 = HH:MM G = Format lainnya - (Minus) di akhir = bilangan negatif diformat dalam warna () (tanda kurung) di akhir = Terdapat kurung pembuka dalam format kode | 
| COLOR | Mengembalikan 1, jika nilai negatif telah diformat dalam warna, jika tidak 0. | 
| PARENTHESES | Mengembalikan 1 jika format kode berisi sebuah kurung pembuka (, jika tidak 0. | 
Referensi (daftar opsi) adalah posisi sel yang diperiksa. Jika Referensi adalah rentang, sel berpindah dari pojok kiri atas rentang. Jika Referensi adalah hilang, LibreOffice Calc menggunakan posisi sel dimana rumus ini berada. Microsoft Excel menggunakan referensi sel dimana kursor berada.
Fungsi ini mengembalikan hasil tanggal mengevaluasi rumus yang dimana ini bagian (dengan kata lain hasil sejauh evaluasi yang didapatkan). Penggunaan utamanya adalah bersama dengan fungsi STYLE() untuk menerapkan gaya terpilih ke sel tergantung pada konten sel.
CURRENT()
=1+2+CURRENT()
Contoh mengembalikan 6. Rumus ini dihitung dari kiri ke kanan sebagai: 1 + 2 sama dengan 3, memberikan hasil kepada tanggal ketika CURRENT() ditemui; CURRENT() karenanya menghasilkan 3, ini ditambahkan ke 3 asli untuk memberikan 6.
=A2+B2+STYLE(IF(CURRENT()>10;"Red";"Default"))
Contoh mengembalikan A2 + B2 (STYLE mengembalikan 0 disini). Jika jumlah ini lebih besar dari 10, gaya Merah diterapkan pada sel. Lihat pada fungsi STYLE untuk penjelasan lebih lanjut.
="choo"&CURRENT()
hasil
ORG.OPENOFFICE.CURRENT
Menampilkan rumus dari sel rumus sebagai teks string.
FORMULA(referensi)
Referensi adalah referensi kepada sel yang berisi sebuah rumus.
Sebuah referensi yang tidak valid atau sebuah referensi kepada sel dengan tidak ada hasil rumus dalam nilai kesalahan #N/A.
jika sel A8 berisi rumus=SUM(1;2;3)kemudian
FORMULA(A8) mengembalikan teks =SUM(1;2;3).
Mengembalikan informasi tertentu tentang lingkungan kerja saat ini. Fungsi menerima sebagai argumen teks tunggal dan mengembalikan data tergantung pada parameter tersebut.
INFO("Tipe")
Tabel berikut mencantumkan nilai untuk parameter teks Tipe dan mengembalikan nilai dari fungsi INFO.
| Nilai untuk "Tipe" | Nilai hasil | 
|---|---|
| "osversion" | Selalu "Windows (32-bit) NT 5.01", untuk alasan kesesuaian | 
| "system" | The type of the operating system:  | 
| "release" | Pengenal rilis produk, untuk contoh "300m25(Build:9876)" | 
| "numfile" | Selalu 1, untuk alasan kesesuaian | 
| "recalc" | Rumus mode perhitungan ulang saat ini, baik "Otomatis" atau "Manual" (diterjemahkan dalam bahasa LibreOffice) | 
Aplikasi Spreadsset lainnya mungkin menerima nilai penerjemahan untuk parameterTipe, tetapi LibreOffice Calc akan hanya menerima nilai Inggris.
=INFO("rilis") mengembalikan angka rilis produk LibreOffice yang digunakan.
=INFO(D5) dengan selD5 berisikan sebuah teks stringsistemmengembalikan tipe sistem operasi.
Mengembalikan TRUE jika referensi ke sebuah sel adalah kosong. Fungsi ini digunakan untuk menentukan jika isi dari sebuah sel adalah kosong. Sebuah cel dengan rumus didalamnya adalah tidak kosong.
ISBLANK(nilai)
Nilai adalah nilai yang akan diperiksa.
=ISBLANK(D2) mengembalikan FALSE sebagai hasil.
Tes untuk kondisi kesalahan, kecuali nilai kesalahan #N/A, dan mengembalikan TRUE atau FALSE.
ISERR(nilai)
Nilai adalah nilai atau ekspresi apa pun yang diuji untuk melihat apakah nilai kesalahan selain #N/A ada.
=ISERR(C8) dimana sel C8 berisi =1/0 menghasilkan TRUE, karena 1/0 adalah kesalahan.
=ISERR(C9) dimana sel C9 berisi =NA() mengembalikan FALSE, karena ISERR() mengabaikan #N/A kesalahan.
Tes untuk kondisi kesalahan, termasuk nilai kesalahan #N/A, dan mengembalikan TRUE atau FALSE.
ISERROR(nilai)
Nilai adalah atau mengacu pada nilai yang diuji coba. ISERROR() mengembalikan TRUE jika terdapat kesalahan dan FALSE jika tidak terdapat kesalahan.
=ISERROR(C8) dimana sel C8 berisi =1/0 mengembalikan TRUE, karena 1/0 adalah kesalahan.
=ISERROR(C9) dimana sel C9 berisi =NA() menghasilkan TRUE.
Returns the value if the cell does not contain an error value, or the alternative value if it does.
IFERROR(Value; Alternate_value)
Nilaiadalah nilai atau ekspresi yang dikembalikan jika tidak setara atau menghasilkan sebuah kesalahan.
Nilai_alternatif adalah nilai atau ekspresi yang dikembalikan jika ekspresi atau nilai dari Nilai adalah setara atau menghasilkan sebuah kesalahan.
=IFERROR(C8;C9) dimana sel C8 berisi =1/0 mengembalikan nilai sel C9, karena 1/0 adalah kesalahan.
=IFERROR(C8;C9) dimana sel C8 berisi 13 mengembalikan 13, nilai dari sel C8, dimana ini bukan sebuah kesalahan.
Mengembalikan TRUE jika nilai bahkan integer, atau FALSE jika nilai adalah ganjil.
ISEVEN(nilai)
Nilai adalah nilai yang akan diperiksa.
Jika nilai tidak sebuah integer, apa saja digit setelah titik desimal diabaikan. Tanda sebuah nilai juga diabaikan.
=ISEVEN(48) mengembalikan TRUE
=ISEVEN(33) mengembalikan FALSE
=ISEVEN(0) mengembalikan TRUE
=ISEVEN(-2.1) mengembalikan TRUE
=ISEVEN(3.999) mengembalikan FALSE
Uji coba untuk angka genap. Mengembalikan 1 apabila angka dibagi oleh 2 mengembalikan keseluruhan angka.
ISEVEN_ADD(Angka)
Nilai adalah nilai yang akan diperiksa.
=ISEVEN_ADD(5) mengembalikan 0.
=ISEVEN_ADD(A1) mengembalikan 1 jika sel A1 berisi angka 2.
Mengembalikan TRUE jika sebuah sel adalah sel rumus.
ISFORMULA(referensi)
Referensi mengindikasi sebuah referensi ke sebuah sel dimana tes akan dilakukan untuk menentukan apakah berisi sebuah rumus.
=ISFORMULA(C4) mengembalikan FALSE jika sel C4 berisi nomor 5.
Uji coba untuk nilai logis (TRUE atau FALSE).
Jika terjadi kesalahan, fungsi mengembalikan FALSE.
ISLOGICAL(nilai)
Mengembalikan TRUE jikaNilai adalah nilai logis (TRUE atau FALSE), dan jika tidak, mengembalikan FALSE.
=ISLOGICAL(99) mengembalikan FALSE, karena 99 adalah nomor, bukan nilai logika.
=ISLOGICAL(ISNA(D4)) mengembalikan TRUE terserah isi sel D4, karena ISNA() mengembalikan sebuah nilai logika.
Mengembalikan TRUE jika sebuah sel berisi #N/A(nilai tidak tersedia) nilai kesalahan.
Jika terjadi kesalahan, fungsi mengembalikan FALSE.
ISNA(nilai)
Nilai adalah nilai yang akan diperiksa.
=ISNA(D3) mengembalikan FALSE sebagai hasil.
Returns the value if the cell does not contain the #N/A (value not available) error value, or the alternative value if it does.
IFNA(Value; Alternate_value)
Nilai adalah nilai atau ekspresi yang dikembalikan jika tidak setara atau menghasilkan sebuah kesalahan #N/A.
Nilai_alternatif adalah nilai atau ekspresi yang dikembalikan jika ekspresi atau nilai dari Nilai adalah setara atau menghasilkan sebuah kesalahan #N/A.
=IFNA(D3;D4) mengembalikan nilai D3 jika D3 tidak menghasilkan kesalahan #N/A, atau D4 jika ada.
Uji coba jika sel berisi teks atau angka, dan mengembalikan FALSE jika isi adalah teks.
Jika kesalahan terjadi, fungsi mengembalikan TRUE.
ISNONTEXT(nilai)
Nilai adalah nilai apa saja atau ekspresi dimana uji coba dilakukan untuk menentukan apakah teks atau angka atau nilai Boolean.
=ISNONTEXT(D2) mengembalikan FALSE jika sel D2 berisi teksabcdef.
=ISNONTEXT(D9) mengembalikan TRUE jika sel D9 berisi angka 8.
mengembalikan TRUE jika nilai mengacu pada bilangan.
ISNUMBER(nilai)
Nilai adalah ekpresi apa saja yang di uji coba untuk menentukan apakah sebuah bilangan atau teks.
=ISNUMBER(C3) mengembalikan TRUE jika sel C3 berisi bilangan 4.
=ISNUMBER(C2) mengembalikan FALSE jika sel C2 berisi teksabcdef.
Mengembalikan TRUE jika nilai adalah ganjil, atau FALSE jika bilangan adalah genap.
ISODD(nilai)
Nilai adalah nilai yang akan diperiksa.
Jika nilai tidak sebuah integer, apa saja digit setelah titik desimal diabaikan. Tanda sebuah nilai juga diabaikan.
=ISODD(33) mengembalikan TRUE
=ISODD(48) mengembalikan FALSE
=ISODD(3.999) mengembalikan TRUE
=ISODD(-3.1) mengembalikan TRUE
mengembalikan TRUE (1) jika bilangan tidak mengembalikan nomor keseluruhan ketika dibagi oleh 2
ISODD_ADD(Angka)
Nilai adalah nilai yang akan diperiksa.
=ISODD_ADD(5) mengembalikan 1.
Menguji apakah argumennya adalah referensi. Mengembalikan TRUE jika argumennya adalah referensi, mengembalikan FALSE jika tidak. Ketika diberi referensi, fungsi ini tidak memeriksa nilai yang direferensikan
ISREF(nilai)
adalah nilai yang akan diuji, untuk menentukan apakah itu sebuah referensi.
=ISREF(C5) mengembalikan hasil TRUE karena C5 referensi yang sah.
=ISREF("abcdef") selalu mengembalikan FALSE karena teks tidak pernah bisa menjadi referensi.
=ISREF(4) mengembalikan FALSE
=ISREF(INDIRECT("A6")) menghasilkan TRUE, karena INDIRECT adalah fungsi yang mengembalikan referensi.
=ISREF(ADDRESS(1; 1; 2;"Sheet2")) mengembalikan FALSE, karena ADDRESS adalah fungsi yang mengembalikan teks, meskipun terlihat seperti referensi.
mengembalikan TRUE jika sel mengacu pada teks.
Jika terjadi kesalahan, fungsi mengembalikan FALSE.
ISTEXT(nilai)
Nilai adalah sebuah nilai, nomor, nilai Boolean, atau nilai kesalahan yang diuji coba.
=ISTEXT(D9) mengembalikan TRUE jika sel D9 berisi teks abcdef.
=ISTEXT(C3) mengembalikan FALSE jika sel C3 berisi nomor 3.
Mengembalikan nilai galat #N/A.
NA()
=NA() konversi isi sebuah sel kedalam #N/A.
Mengembalikan nilai numerik dari parameter yang diberikan. Mengembalikan 0 jika parameter adalah teks atau FALSE.
Jika terjadi kesalahan, fungsi mengembalikan nilai kesalahan.
N(nilai)
Nilai adalah parameter yang dikonversi ke sebuah bilangan. N() mengembalikan nilai numerik jika bisa. Ini mengembalikan nilai logika TRUE dan FALSE sebagai 1 dan 0 masing masing. Ini mengembalikan teks sebagai 0.
=N(123) mengembalikan 123
=N(TRUE()) mengembalikan 1
=N(FALSE()) mengembalikan 0
=N("abc") mengembalikan 0
=N(1/0) mengembalikan #DIV/0!
Mengembalikan tipe sebuah nilai, dimana 1 = bilangan, 2 = teks, 4 = nilai Boolean, 8 = rumus, 16 = nilai kesalahan, 64 = array.
TYPE(nilai)
Nilai adalah nilai tertentu yang dimana tipe data ditentukan.
=TYPE(C2) mengembalikan 2 sebagai hasil.
=TYPE(D9) mengembalikan 1 sebagai hasil.