LibreOffice 24.8 Bantuan
LibreLogo adalah suatu lingkungan pemrograman mirip Logo yang sederhana dan terlokalisasi dengan grafik vektor kura-kura untuk mengajar komputasi (pemrograman dan pengolahan kata), DTP, dan disain grafis. Lihat http://www.numbertext.org/logo/librelogo.pdf.
Bilah alat LibreLogo ) berisi kura-kura bergerak, memulai program, berhenti, layar yang jelas, penyunting program/penyorotan syntax/penerjemahan ikon dan sebuah bar input (baris perintah)
Mereka adalah ekuivalen dari perintah Logo "FORWARD 10", "BACK 10", "LEFT 15", "RIGHT 15". Mengklik pada salah satu ikon juga akan memfokuskan bentuk kura-kura menggulir halaman ke posisinya.
Klik pada ikon "Mulai program Logo" untuk mengeksekusi teks (atau hanya yang dipilih) teks dokumen Writer sebagai program LibreLogo. Dalam dokumen kosong, sebuah contoh program akan disisipkan dan dijalankan.
klik pada ikon "Stop" untuk menghentikan eksekusi program.
Klik pada ikon "Rumah" untuk menata ulang posisi dan pengaturan pada kura kura
Klik pada ikon "layar yang jelas" untuk menghilangkan objek gambar pada dokumen
Ikon "tongkat ajaib" mengatur tata letak 2 halaman untuk penyuntingan program, memperluas dan mengubah ke huruf besar perintah-perintah Logo yang disingkat dan huruf kecil dalam dokumen Writer. Ubah bahasa dokumen ( dan klik pada ikon ini untuk menerjemahkan program Logo ke bahasa yang dipilih.
Tekan Enter di baris perintah untuk mengeksekusi kontennya. Untuk menghentikan program, gunakan ikon "Stop".
Tahan Enter untuk mengulang baris perintah, misalnya, pada urutan perintah berikut:
MAJU 200 KIRI 89
Untuk mengatur ulang baris perintah, klik tiga kali atau tekan CommandCtrl+A untuk memilih perintah sebelumnya, dan ketikkan perintah baru.
Bentuk penyu dari LibreLogo adalah objek gambar ukuran tetap yang normal. Anda dapat memosisikan dan memutarnya dengan cara standar, juga menggunakan tetikus dan ikon Putar dari bilah alat Properti Objek Menggambar. Ubah pengaturan Tebal Garis, Warna Garis, dan Warna Area dari bentuk kura-kura untuk menata atribut PENSIZE, PENCOLOR, dan FILLCOLOR dari LibreLogo.
Gambar dan program LibreLogo menggunakan dokumen Penulis yang sama. Kanvas LibreLogo ada di halaman pertama dokumen Writer. Anda dapat menyisipkan jeda halaman sebelum program LibreLogo dan mengatur zoom halaman menggunakan ikon "tongkat ajaib" dari bilah alat Logo, juga mengubah ukuran fon untuk tata letak 2-halaman yang nyaman untuk pemrograman LibreLogo: halaman kiri (depan) adalah kanvas , halaman kanan (kedua) adalah editor program LibreLogo.
LibreLogo adalah bahasa pemrograman yang mudah dilokalkan, seperti Logo, dilokalkan dalam beberapa bahasa oleh komunitas bahasa asli LibreOffice. Itu kembali kompatibel dengan sistem Logo yang lebih tua dalam kasus program Logo sederhana yang digunakan dalam pendidikan, misalnya.
UNTUK segi tiga :ukuran
ULANGI 3 [
MENERUSKAN :ukuran
KIRI 120
]
SELESAI
segitiga 10 segitiga 100 segitiga 200
Daftar anggota dipisahkan koma: POSISI [0, 0]
posisi Program blok dan daftar berbeda
Blok program membutuhkan ruang atau baris baru pada tanda kurung: ULANGI 10 [MENERUSKAN 10 KIRI 36]
Daftar harus tanda kurung yang dekat: POSITION [0, 0], dan bukan POSITION [ 0, 0 ]
Deklarasi fungsi 1-baris tidak didukung (TO dan END membutuhkan baris baru).
Tanda petik dua adalah pilihan sebelum nama variabel
Untuk ukuran tiga
ULANGI 3 [DEPAN ukuran KIRI 120]
SELESAI
Notasi kata mendukung ortografis dan syntax Python
PRINT "kata ; sintaksis Logo asli
PRINT “Teks arbitrari.” ; ortografi, Writer
PRINT 'Teks arbitrari' ; Sintaksis Python
Daftar Python dan penanganan string
PRINT “teks”[2] ; cetak “x”
PRINT “teks”[1:3] ; print “ex”
Loop FOR mirip Python
Deklarasi variabel mirip-Python:
x = 15
CETAK x
Tidak ada fungsi kueri tambahan:
CETAK ISITINTA
p = POSISI
CETAK p
ULANGI 10 [ POSISI SETIAP POSISI p ]
Pengantar alternatif dalam panggilan fungsi
TO star size color
FILLCOLOR color
REPEAT 5 [ LEFT 72 FORWARD size RIGHT 144 FORWARD size ]
FILL
END
star 100 “red”
star(100, “green”)
star(100, “blue”)
Perintah, konstanta warna tidak peka:
PRINT “Halo, Dunia!”
print “Halo lagi Dunia!”
Nama-nama variabel adalah peka kapital:
a = 2
A = 9
PRINT a
PRINT A
Baris dari program LibreLogo adalah paragraf dalam dokumen Writer. Baris program dapat berisi beberapa perintah:
PRINT “Hello, World!” PRINT “LibreLogo”
Garis atau bagian garis adalah komentar dari titik koma hingga akhir baris (paragraf):
; beberapa komentar.
PRINT 5 * 5 ; beberapa komentar.
Anda dapat memisahkan baris program untuk lebih banyak paragraf menggunakan karakter tilde di akhir baris:
PRINT “This is a very long ” + ~
“warning message”
KE DEPAN 10 ; PINDAH KE DEPAN 10pt (1pt = 1/72 inci)
KE DEPAN 10pt; lihat ke atas
KE DEPAN 0.5 inci ; pindah ke depan 0.5 inci (1 inci = 2.54 cm)
KE DEPAN 1' ; lihat ke atas
FD 1mm
FD 1cm
KE BELAKANG 10; pindah ke belakang 10pt
KE KIRI 90; putar berlawanan dengan jarum jam 90 derjat
Kiri 90°; lihat ke atas
LT 3h; lihat ke atas (posisi jam)
LT apapun ; putar posisi secara acak
KE KANAN 90 ; putar searah jarum jam 90 derajat
PENUP ; turtle akan bergerak tanpa menggambar
PENDOWN ; turtle akan bergerak dengan menggambar
POSISI[0, 0] ; putar dan bergerak ke pojok kanan-atas
POSISI UKURAN AHALAMAN ; putar dan bergerak ke pojok kiri bawah
POSISI [UKURAN HALAMAN[0], 0] ; putar dan bergerak ke pojok kanan atas
POSISI APAPUN ; putar dan bergerak ke posisi acak
HEADING 0 ; putar ke utara
HEADING 12h ; lihat ke atas
HEADING [0, 0]; putar ke pojok kiri atas
HEADING APAPUN ; putar ke arah acak
HIDETURTLE; sembunyukan kura-kura (hingga perintah showturtle)
SHOWTURTLE ; tampilkan turtle
HOME ; atur ulang posisi awal turtle
CLEARSCRENN ; hapus objek gambar dari dokumen
ISI ; tutup dan isi bentuk garis atau titik asli
TUTUP ; tutup bentuk garis asli atau gabungkan titik asli
Contoh; mengisi sebuah segitiga reguler:
KE DEPAN 50 KE KIRI 120 KE DEPAN 50 ISI
Contoh; mengisi sebuah segitiga reguler:
KE DEPAN 50 KE KIRI 120 KE DEPAN 50 ISI
PENSIZE 100 ; tebal garis 100 point
PENSIZE ANY ; ekuivalen dengan PENSIZE RANDOM 10
PENCOLOR “merah” ; mengatur warna pena merah (dengan nama warna, lihat konstanta warna)
PENCOLORO [255, 255, 0] ; mengatur warna pena kuning (daftar RGB)
PENCOLOR 0xffff00 ; mengatur warna kuning (kode heksa)
PENCOLOR 0 ; mengatur warna hitam (0x000000)
PENCOLOR ANY ; warna acak
PENCOLOR [5] ; mengatur warna pena merah (via pengidentifikasi warna, lihat konstanta warna)
PENCOLOR “tak terlhiat” ; warna pena tak terlihat untuk bentuk tanpa garis tepi yang terlihat
PENCOLOR “~merah” : mengatur warna merah acak
PENTRANSPARENCY 80 ; mengatur transparansi warna pena asli ke 80%
PENCAP “tak ada” : tanpa ujung garis tambahan (bawaan)
PENCAP “bulat” ; ujung garis di bulatkan
PENCAP “kotak” ; ujung garis kotak
PENJOINT “dibulatkan” ; pertemuan garis dibulatkan (bawaan)
PENJOINT “siku" ; pertemuan garis tajam
PENJOINT “miring” pertemuan garis miring
PENJOINT “tak ada” ; tanpa pertemuan garis
PENSTYLE “solid” ; garis solid (bawaan)
PENSTYLE “titik” ; garis bertitik
PENSTYLE “strip” ; garis strip
; ditentukan oleh daftar dengan argumen berikut:
; – jumlah titik yang berdekatan
; – panjang titik
; – jumlah strip yang berdekatan
; – panjang strip
; – jarak titik/strip
; - tipe (opsinal):
; 0 = titik berupa persegi (baku)
; 2 =titik berupa kotak (panjang dan relatif terhadap ukuran pena)
PENSTYLE [3, 1mm, 2, 4mm, 2mm, 2] ; ...––...––...––
FILLCOLOR “biru” ; isi dengan warna biru, lihat pula PENCOLOR
FILLCOLOR “tak tampak” LINGKARAN 10 ; tidak lingkaran tak berisi
FILLCOLOR [“biru”, “merah”] ; gradien antara merah dan biru
FILLCOLOR [[255, 255, 255], [255,128,0]] ; antara putih dan oranye
FILLCOLOR [“birut”, “merah”, 1, 0, 0] ; atur gradien aksial (dengan pengaturan rotasi dan batas yang diperlukan), nilai yang memungkinan: 0-5 = linear, aksial, radial, lonjong, kotak dan gradien persegi
FILLCOLOR [“merah”, “biru”, 0, 90, 20] ; linear dengan 20% batas, diputar 90 derajat daritajuk asli turtle
FILLCOLOR [“merah”, “biru”, 0, 90, 20, 0, 0, 200, 50] ; dari 200% to 50% intensit
FILLCOLOR [ANY, ANY, 2, 0, 0, 50, 50] ; gradien radial dengan warna acak dan 50-50% posisi horisontal dan vertikal dari pusat
FILLTRANSPARENCY 80 ; mnengatur transparansi dari warna isian asli ke 80%
FILLTRANSPARENCY [80] ; mengatur transparansi linier gradien dari 80% ke 0%
FILLTRANSPARENCY [80, 20] ; mengatur transparansi linier gradien dari 80% tke 20%
FILLTRANSPARENCY [80, 20, 1, 90] ; mengatur transparansi aksial gradien diputar 90 derajat dari tajuk asli turtle
FILLTRANSPARENCY [80, 20, 2, 0, 20, 50, 50] ; mengatur transparansi redial gradien dari luar 80% ke dalam 20% transparan dengan 20% batas dan dengan 50-50% posisi horisontal dan vertikal positions dari pusat
FILLSTYLE 0 ; isian tanpa arsiran (baku)
FILLSTYLE 1 ; arsiran tunggal hitam (horisontal)
FILLSTYLE 2 ; arsiran tunggal hitam (45 derajat)
FILLSTYLE 3 ; arsiran tunggal hitam (-45 derajat)
FILLSTYLE 4 ; arsiran tunggal hitam (vertikal)
FILLSTYLE 5 ; arsiran silang merah (45 derajat)
FILLSTYLE 6 ; arsiran silang merah (0 derajat)
FILLSTYLE 7 ; arsiran silang biru (45 derajat)
FILLSTYLE 8 ; arsiran silang biru (0 derajat)
FILLSTYLE 9 ; arsiran triple biru
FILLSTYLE 10 ; arsiran tunggal lebar hitam (45 derajat)
; arsiran ubahan spesifik dengan daftar dengan argumen berikut:
; – gaya (1 = tunggal, 2 = ganda, 3 = triple)
; – warna
; – jarak
; – derajat
FILLSTYLE [2, “hijau”, 3pt, 15°] ; arsiran silang hijau (15 derajat)
LINGKARAN 100 ; gambar bentuk lingkaran (diameter = 100pt)
ELIPS [50, 100] ; gambar bentuk elips dengan diameter 50 dan 100
ELLIPSE [50, 100, 2h, 12h] ; gambar sektor elips (dari posisi pukul 2 hingga pukul 12)
ELIPS [50, 100, 2h, 12h, 2] ; gambar segmen elips
ELIPS [50, 100, 2h, 12h, 3] ; gambar busur elips
KOTAK 100; gambar bentuk kotak (ukuran = 100pt)
PERSEGI [50, 100] ; gambar bentuk persegi (50×100pt)
PERSEGI [50, 100, 10] ; gambar bentuk persegi dengan pojok yang dibulatkan
TITIK ; menggambar titik dengan ukuran dan warna pena
TUTUP dapan menggabungkan titik terakhir, ISIAN dapat mengisi bentuk yang ditentukan berdasarkan titik. Sebagai contoh, lebih mudah untuk menggambar bintang “datar” mulai dari pusatnya:
PENUP
ULANGI 5 [
KE DEPAN 80
TITIK
KE BELAKANG 80
KE KANAN 36
KE DEPAN 50
TITIK
KE BELAKANG 50
KANAN 120
] ISIAN
LABEL “teks” ; cetak teks di posisi turtle
LABEL 'teks' ; lihat di atas
LABEL "teks ;lihat di atas (hanya untuk kata tunggal)
LINGKARAN 10 TEKS “teks” ; mengatur teks objek gambar yang asli
FONTCOLOR “hijau” ; mengatur warna fonta
FONTFAMILY “Linux Libertine G” ; mengatur (keluarga) fonta
FONTFAMILY “Linux Libertine G:smcp=1” ; mengatur pula fitur fonta (kap kecil)
FONTFAMILY “Linux Libertine G:smcp=1&onum=1” ; kap kecil + figur lawas
FONTSIZE 12 ; mengatur 12pt
FONTWEIGHT “tebal” ; mengatur ketebalan fonta
FONTWEIGHT “normal” ; mengatur berat norma
FONTSTYLE “cetak miring” ; mengatur varian cetak miring
FONTSTYLE “normal” ; mengatur variasi normal
CITRA untuk
pengelompokan bentuk;
memulai bentuk garis baru;
menyimpan gambar SVG dan animasi SVG/SMIL;
menjaga konsistensi posisi dan bentuk garis pada batas kiri.
; CITRA [ LibreLogo_commands ]
CINTRA [ MAJU KE 100 LINGKARAN 100 ] ; bentuk berkelompok seperti pohon
Lihat juga “Group” di LibreOffice Writer Help.
TO tree location
PENUP POSITION location HEADING 0 PENDOWN
PICTURE [ FORWARD 100 CIRCLE 100 ] ; bentuk yang dikelompokkan mirip pohon
END
PICTURE [ tree [230, 400] tree [300, 400] ] ; bentuk yang dikelompokkan dalam bentuk yang dikelompokkan
CITRA ; mulai bentuk garis baru
KE DEPAN 10 CITRA KE DEPAN 10 ; dua bentuk garis
CINTRA “contoh.svg” [ LINGKARAN 5 ] ; simpan gambar sebagai citra SVG dalam direktori pengguna
CITRA “Desktop/contoh.svg” [ KE DEPAN 100 LINGKARAN 5 ] ; sebagaimana di atas, dengan alamat relatif
CITRA “/home/user/contoh.svg” [ LINGKARAN 5 ] ; alamat absolut untuk Unix/Linux
CITRA “C:\contoh.svg” [ LINGKARAN 5 ] ; alamat absolut untuk Windows
CITRA “animation.svg” [ CIRCLE 5 SLEEP 1000 CIRCLE 99 ] ; simpan sebagai animasi SVG/SMIL (lihat juga SLEEP)
CITRA “animation2.svg” [ CIRCLE 5 SLEEP 1000 CIRCLE 99 SLEEP 2000 ] ; sebagaiaman di atas, tetapi menggunakan SLEEP setelah objek terakhir dengan hasi berupa pengulangan setelah dua detik animasi SVG dijalankan ulang dalam peramban SMIL-conformant
Gunakan CITRA untuk menjaga konsistensi posisi dan bentuk garis pada batas kiri Writer:
PICTURE [ CIRCLE 20 POSITION [-100, 100] CIRCLE 20 ]
; ULANG nomor [ commands ]
ULANGI 10 [ M 10 LEFT 45 CIRCLE 10 ] ; ulangi 10 kali
; angka bersifat opsional
ULANGI [ POSITION ANY ] ; perulangan tanpa henti
variabel perulangan (juga terdapat dalam perulangan FOR dan WHILE).
REPEAT 100 [ FORWARD REPCOUNT LEFT 90 ]
Perulangan untuk daftar elemen-elemen:
FOR i IN [1, 5, 7, 9, 11] [
FORWARD i
LEFT 90
]
Perulangan untuk karakter dari urutan karakter:
FOR i IN “text” [
LABEL i
FORWARD 10
]
WHILE TRUE [ POSITION ANY ] ; perulangan tanpa henti
WHILE REPCOUNT <= 10 [ FORWARD 50 LEFT 36 ] ; as REPEAT 10 [ ... ]
Hentikan pengulangan.
REPEAT [ ; perulangan tanpa henti
POSITION ANY
IF REPCOUNT = 100 [ BREAK ] ; setara dengan REPEAT 100 [ ... ]
]
Melompat ke iterasi pengulangan selanjutnya.
REPEAT 100 [
POSITION ANY
IF REPCOUNT % 2 = 0 [ CONTINUE ]
CIRCLE 10 ; gambar lingkaran pada tiap posisi kedua
]
; IF condition [ true block ]
; IF condition [ true block ] [ false block ]
IF a < 10 [ PRINT “Kecil” ]
IF a < 10 [ PRINT “Small” ] [ PRINT “Besar” ]
Operator lojik.
IF a < 10 AND NOT a = 5 [ PRINT “0, 1, 2, 3, 4, 6, 7, 8 or 9” ]
IF a < 10 AND a != 5 [ PRINT “0, 1, 2, 3, 4, 6, 7, 8 or 9” ] ; sebagaimana di atas
Kata baru (atau prosedur).
UNTUK segitiga
ULANGI 2 [ FORWARD 100 RIGHT 120 ] FILL
AKHIR
ULANGI 10 [ segitiga PENUP POSITION ANY PENDOWN ]
Mengembalikan nilai dari fungsi.
TO randomletter
LUARAN ACAK “qwertzuiopasdfghjklyxcvbnm”
END
PRINT randomletter + randomletter + randomletter ; print 3-surat urutan karakter acak
Kembali dari prosedur.
UNTUK angka contoh
IF angka < 0 [ STOP ]
PRINT SQRT angka ; print kotak root
]
contoh 100
contoh -1 ; tanpa luarandan galat
contoh 25
Nilai acak baku dari angka, dll.
PENCOLOR ANY ; warna pena acak
Nilai lojik.
WHILE TRUE [ POSITION ANY ] ; perulangan tak henti
PRINT TRUE ; print true
Nilai lojik.
WHILE NOT FALSE [ POSITION ANY ] ; perulangan tak henti
PRINT FALSE ; print false
PRINT PAGESIZE ; daftar cettak ukuran halaman dalam satuan point, mis. [595.30, 841.89]
PRINT PI ; mencetak 3.14159265359
PRINT “teks” ; print “teks” dalam sebuah kotak dialog
PRINT 5 + 10 ; print 15
PRINT INPUT “Input value?” ; meminta dan mencetak string berdasarkan kueri kotak dialog
PRINT FLOAT (INPUT “First number?”) + FLOAT (INPUT “Angka kedua?”) ; kalkulator sederhana
SLEEP 1000 ; wait for 1000 ms (1 sec)
Mengatur variabel global yang digunakan dalam prosedur.
GLOBAL tentang
tentang = “LibreLogo”
TO contoh
PRINT tentang
GLOBAL tentang ; ketika kami ingin menambahkan nilai baru
tentang = “nilai baru untuk variabel global”
END
contoh
PRINT tentang
PRINT RANDOM 100 ; angka float acak (0 <= x < 100)
PRINT RANDOM “text” ; huruf acak dari “teks”
PRINT RANDOM [1, 2] ; daftar elemen acak (1 atau 2)
PRINT INT 3.8 ; print 3 (integer part of 3.8)
PRINT INT RANDOM 100 ; angka integer acak (0 <= x < 100)
PRINT INT “7” ; konversi paramater string to integer
; konfersi parameter string ke angka float
PRINT 2 * FLOAT “5.5” ; print 11.0
; konversi parameter angka ke string
PRINT “Hasil: ” + STR 5 ; print “Result: 5”
PRINT 10 * STR 5 ; print 5555555555
PRINT SQRT 100 ; cetak 10, akar kuadrat dari 100
PRINT SIN 90 * PI/180 ; cetak 1.0 (sinus of 90° dalam radian)
PRINT COS 0 * PI/180 ; cetak 1.0 (cosinus of 0° dalam radian)
PRINT LOG10 100 ; print 2.0 (logaritma umum dari 100)
PRINT ROUND 3.8 ; print 4 (rounding 3.8)
PRINT ROUND RANDOM 100 ; angka integer acak (0 <= x <= 100)
PRINT ABS -10 ; print 10, nilai absolut dari -10
PRINT COUNT “teks” ; print 4, hitang karakter dari “text”
PRINT COUNT [1, 2, 3] ; print 3, ukuran dari daftar
; Konversi daftar ke set Python
PRINT SET [4, 5, 6, 6] ; print {4, 5, 6}
PRINT SET [4, 5, 6, 6] | SET [4, 1, 9] ; print {1, 4, 5, 6, 9}, union
PRINT SET [4, 5, 6, 6] & SET [4, 1, 9] ; print {4}, intersection
PRINT SET ([4, 5, 6, 6]) - SET [4, 1, 9] ; print {5, 6}, difference
PRINT SET [4, 5, 6, 6] ^ SET [4, 1, 9] ; print {1, 5, 6, 9}, perbedaan simetris
; Pembuatan senarai mirip Python
PRINT LIST RANGE 10 ; print [0, 1, 2, 3, 4, 5, 6, 7, 8, 9]
PRINT LIST RANGE 3 10 ; print [3, 4, 5, 6, 7, 8, 9]
PRINT LIST RANGE 3 10 3 ; print [3, 6, 9]
FOR i IN RANGE 10 50 10 [ ; loop untuk [10, 20, 30, 40]
FORWARD i
LEFT 90
]
hapus pengulangan elemen dari daftar menggunakan konversi set dan daftar
PRINT LIST (SET [1, 3, 5, 5, 2, 1]) ; print [1, 3, 5, 2]
Konversi ke tuple Python (daftar tidak dapat dimodifikasi)
PRINT TUPLE [4, 5]
Hal ini kembali dengan daftar yang telah disortir.
PRINT SORTED [5, 1, 3, 4] ; print [1, 3, 4, 5]
Urutkan urutan karakter menggunakan pola regex (regular expression/ekspresi reguler).
PRINT SUB (“t”, “T”, “teks”) ; print “Teks”, mengganti “t” dengan “T”
PRINT SUB (“(.)”, “\\1\\1”, “tek”) ; print “tteekkss”, menggandakan setiap karakter
Cari pola urutan karakter menggunakan pola regex.
IF SEARCH (“\w”, "word") [ PRINT “Huruf di dalam kata.” ]
Temukan semua urutan karakter dalam masukan string yang cocok dengan pola regex yang diberikan.
PRINT FINDALL(“\w+”, “Anjing, kucing.”) ; print [“Anjing”, “kucing”], daftar kata.
PRINT MIN [1, 2, 3] ; print 1,elemen terendah dari daftar
PRINT MAX [1, 2, 3] ; print 3, elemen terbesar dari daftar
PENCOLOR “SILVER” ; set by name
PENCOLOR [1] ; diatur oleh pengenal
PENCOLOR “~SILVER” ; warna silver acak
| Pengenal | Nama | 
|---|---|
| 0 | BLACK | 
| 1 | SILVER | 
| 2 | GRAY/GREY | 
| 3 | WHITE | 
| 4 | MAROON | 
| 5 | RED | 
| 6 | PURPLE | 
| 7 | FUCHSIA/MAGENTA | 
| 8 | GREEN | 
| 9 | LIME | 
| 10 | OLIVE | 
| 11 | YELLOW | 
| 12 | NAVY | 
| 13 | BLUE | 
| 14 | TEAL | 
| 15 | AQUA | 
| 16 | PINK | 
| 17 | TOMATO | 
| 18 | ORANGE | 
| 19 | GOLD | 
| 20 | VIOLET | 
| 21 | SKYBLUE | 
| 22 | CHOCOLATE | 
| 23 | BROWN | 
| 24 | INVISIBLE |